www.gusucode.com > 深度学习(asp)网址导航 v4.0.1 > 深度学习(asp)网址导航 v4.0.1\code\include\function.tag.template.asp
<%
'┌──────────────────── 深度空间 深度学习 ──┐
'│过程名：channel 网站频道
'│作 用：显示对应位置频道
'│参 数：iPlace 位置 0上 1 下
'│说 明：
'│日 期：2009-6-30
'└──────────────────── www.deepstudy.cn ──┘
function getHTML_channel(iPlace)
dim sql,strHTML : strHTML=""
sql="select fviewType,flinkUrl,ftip,fname,fid,openTarget from deep_Channel where fparentID=0 and fisView=1 and fplace="&iPlace&" order by forderID,fid"
set rsChannel=conn.execute(sql)
if (rsChannel.eof and rsChannel.bof) then
'response.Write("没有导航")
else
strHTML=strHTML & "<ul>"
while (not rsChannel.eof)
strHTML=strHTML & "<li><a href='"
if (rsChannel("fviewType")=0)then
if(left(rsChannel("flinkUrl"),7)="http://" or left(rsChannel("flinkUrl"),1)="/")then
strHTML=strHTML & rsChannel("flinkUrl")&"' "
else
' 生成静态页判断
if(isCreateHTML=true) then
strHTML=strHTML & projectRoot2htmlPath & rsChannel("flinkUrl")&"' "
else
strHTML=strHTML & projectRootPath & rsChannel("flinkUrl")&"' "
end if
end if
else
' 生成静态页判断
if(isCreateHTML=true) then
strHTML=strHTML & projectRoot2htmlPath&"html/channel/" & "channel_"&rsChannel("fid")&".htm' "
else
strHTML=strHTML & projectRootPath & "channel.asp?id="&rsChannel("fid")&"' "
end if
end if
if (rsChannel("openTarget")=1)then
strHTML=strHTML & " target='_blank'"
end if
strHTML=strHTML & " title='"&rsChannel("ftip")&"'>"&rsChannel("fname")&"</a></li>"
rsChannel.moveNext
wend
strHTML=strHTML& "<li class=""separation""> </li></ul>"
end if
rsChannel.close
set rsChannel=nothing
getHTML_channel=strHTML
end function
'┌──────────────────── 深度空间 深度学习 ──┐
'│函数名：showAdvert
'│作 用：广告显示
'│参 数：id id号
'│返回值：
'│说 明： 广告调用：在需要调用的地方插入 《% call showAdvert(广告id号) %》 即可。
'│日 期：2006/4/8 2009-6-25
'└──────────────────── www.deepstudy.cn ──┘
function showAdvert(id)
dim sql,jsSrcIdName,jsSrcName,strHTML: strHTML=""
sql = "SELECT * FROM deep_Advertisement WHERE fisView=1 and fid=" & id
Set rsAdvert = conn.execute(sql)
If (Not rsAdvert.EOF) Or (Not rsAdvert.BOF) Then
While (Not rsAdvert.EOF)
'广告类型 0程序代码 1图片 2flash 3弹窗 4浮动
select case rsAdvert("fADType")
case 0
strHTML=strHTML & rsAdvert("fADCode")
case 1
strHTML=strHTML & "<div style=""background-image:url("&site_upFilesDir&"drumbeating/"&rsAdvert("fADCode")&"); width:"&rsAdvert("fwidth")&"px; height:"&rsAdvert("fheight")&"px;background-repeat:no-repeat;""></div>"
case 2
jsSrcIdName=left(trim(rsAdvert("fADCode")) , len( trim(rsAdvert("fADCode")) )-4 )
jsSrcName=site_upFilesDir&"drumbeating/" & trim( rsAdvert("fADCode") )
strHTML=strHTML & "<script type=""text/javascript"" src=""js/swfobject.js""></script>"
strHTML=strHTML & "<script type=""text/javascript"">"
strHTML=strHTML & "swfobject.embedSWF("""&jsSrcName&""", ""id_"&jsSrcIdName&""", """&rsAdvert("fwidth")&""", """&rsAdvert("fheight")&""", ""9.0.0"");"
strHTML=strHTML & "</script>"
strHTML=strHTML & "<div id=""id_"&jsSrcIdName&"""></div> "
case 3
'strHTML=strHTML & rsAdvert("fADCode")
'弹窗
strHTML=strHTML & "<script Language=""JavaScript"">"
strHTML=strHTML & "window.open ('popup.asp?id="&rsAdvert("fid")&"', '', 'width="&rsAdvert("fwidth")&",height="&rsAdvert("fheight")&", top=0, left=0, toolbar=no, menubar=no, scrollbars=no, resizable=no,location=no, status=no');"
strHTML=strHTML & ""
strHTML=strHTML & "</script>"
case 4 '=====浮动图标广告 开始====
strHTML=strHTML & "<div id='ad' style='position:absolute;width:"&rsAdvert("fwidth")&"px;height:"&rsAdvert("fheight")&"px; z-index:20; background-color:#f0f0f0'>"&rsAdvert("fADCode")&"</div>"
strHTML=strHTML & "<script type=""text/javascript"">"
strHTML=strHTML & " function scrollImg(){"
strHTML=strHTML & " var posX,posY;"
strHTML=strHTML & " if (window.innerHeight) {"
strHTML=strHTML & " posX = window.pageXOffset;"
strHTML=strHTML & " posY = window.pageYOffset;"
strHTML=strHTML & " }"
strHTML=strHTML & " else if (document.documentElement && document.documentElement.scrollTop) {"
strHTML=strHTML & " posX = document.documentElement.scrollLeft;"
strHTML=strHTML & " posY = document.documentElement.scrollTop;"
strHTML=strHTML & " }"
strHTML=strHTML & " else if (document.body) {"
strHTML=strHTML & " posX = document.body.scrollLeft;"
strHTML=strHTML & " posY = document.body.scrollTop;"
strHTML=strHTML & " }"
strHTML=strHTML & " var ad=document.getElementById(""ad"");"
strHTML=strHTML & " ad.style.top=(posY+400)+""px"";"
'//ad.style.left=(posX+700)+"px";
strHTML=strHTML & " ad.style.left=(document.body.scrollWidth- "&rsAdvert("fwidth")&" -10)+""px"";"
strHTML=strHTML & " setTimeout(""scrollImg()"",100);"
strHTML=strHTML & " }"
strHTML=strHTML & " scrollImg();"
strHTML=strHTML & " </script>"
'<script type="text/javascript">
'< /script>
'=== 浮动图标广告 结束 ==
end select
rsAdvert.MoveNext
Wend
End If
rsAdvert.Close()
Set rsAdvert = Nothing
showAdvert = strHTML
End function
'┌──────────────────── 深度空间 深度学习 ──┐
'│过程名：getHTML_siteInfoStatistic
'│作 用：网站站内统计
'│参 数：无
'│说 明：需在文章头部包含 此过程自动添加
'│日 期：2009-6-26
'└──────────────────── www.deepstudy.cn ──┘
function getHTML_siteInfoStatistic()
dim sql,rs,strHTML : strHTML=""
sql= "Select Count(*) from deep_WebSort"
Set rs=conn.Execute(sql)
strHTML=strHTML & "□ - 网址分类 ：<font color=""#FF0000"">"&rs(0)&"</font> 篇<br />"
sql= "Select Count(*) from deep_WebUrl"
set rs=conn.Execute(sql)
strHTML=strHTML & "□ - 网站总数 ：<font color=""#FF0000"">"& rs(0)& "</font> 个<br />"
rs.close
Set rs = Nothing
strHTML=strHTML & "□ - 当前在线 ：<font color=""#FF0000"">"& onlineCount() &"</font> 人<br />"
getHTML_siteInfoStatistic=strHTML
end function
'┌──────────────────── 深度空间 深度学习 ──┐
'│过程名：getHTML_friendLink
'│作 用：网站友情链接
'│参 数：无
'│说 明：需在文章头部包含 此过程自动添加
'│日 期：2009-6-26
'└──────────────────── www.deepstudy.cn ──┘
function getHTML_friendLink()
dim sql,rs,strHTML : strHTML=""
sql="select furl,ftip,flinkType,fname,flogoUrl from deep_FriendLink where fisView=1 order by forderID,fid"
set rs=conn.execute(sql)
if(rs.eof and rs.bof) then
'response.Write("暂时没有链接")
else
strHTML= strHTML & "<ul id='friendLink'>"
while (not rs.eof)
if (rs("flinkType")=0) then
strHTML= strHTML & "<li><a href='"&rs("furl")&"' target='_blank' title='"&rs("ftip")&"'>"&rs("fname")&"</a></li>"
else
if (left( rs("flogoUrl") ,7 )="http://" or left(rs("flogoUrl"),1)="/") then
FriendSite_logoUrl=rs("flogoUrl")
else
' 生成静态页判断
if(isCreateHTML=true) then
FriendSite_logoUrl=projectRoot2htmlPath & site_upFilesDir & "friendlink/" & rs("flogoUrl")
else
FriendSite_logoUrl=projectRootPath & site_upFilesDir & "friendlink/" & rs("flogoUrl")
end if
end if
strHTML= strHTML & "<li><a href='"&rs("furl")&"' target='_blank' title='"&rs("ftip")&"' style='background-image:url("&FriendSite_logoUrl&")'></a></li>"
end if
rs.moveNext
wend
strHTML= strHTML & "</ul><div class='clear'></div>"
end if
rs.close
set rs=nothing
getHTML_friendLink = strHTML
end function
%>